Hi,

This next guide adds a little extra gloss to our moving sprite demonstration by showing users how simple it is to add any number of animation frames to a sprite, creating a greater impression of movement.

As before you can find the resulting code posted below and I encourage you to cut and paste it into the AppGameKit IDE and play around with it yourself.


// Project: making a sprite move.
// Created: 2014-11-21

// set window properties
SetWindowTitle( "making a sprite move." )

// set variables
screenwidth=1024
screenheight=768
fullscreen=0

// set display properties for platforms that support windows, e.g., Windows or Mac.

SetWindowSize(screenwidth,screenheight,fullscreen )

// set display properties for mobile devices.

SetVirtualResolution(screenwidth,screenheight)


// Set up a sprite data

balloonsprite=1
balloonx=512
balloony=384
balloondirection=1


// create a sprite with ID that uses the balloon image
CreateSprite (balloonsprite,0)

AddSpriteAnimationFrame(balloonsprite,LoadImage("item0.png"))
AddSpriteAnimationFrame(balloonsprite,LoadImage("item1.png"))
AddSpriteAnimationFrame(balloonsprite,LoadImage("item2.png"))
AddSpriteAnimationFrame(balloonsprite,LoadImage("item3.png"))
AddSpriteAnimationFrame(balloonsprite,LoadImage("item4.png"))

PlaySprite (balloonsprite)

// Main loop

do

// set the sprite position.
SetSpritePosition (balloonsprite,balloonx,balloony)

//move the balloon along the X axis by the amount specified by balloondirection
balloonx=balloonx+balloondirection

// check to see if the balloon is near the far right edge of the screen and if so, reverse direction
if balloonx+GetSpriteWidth(balloonsprite)>screenwidth
balloondirection=-1
endif

// check to see if the balloon is near the far left edge of the screen and if so, reverse direction
if balloonx<1
balloondirection=1
endif


Sync()
loop